# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Contributor: D. Can Celasun <dcelasun[at]gmail[dot]com>
# Contributor: Felix Hanley <felix@seconddrawer.com.au>
# Contributor: Sławomir Kowalski <suawekk@gmail.com>

pkgname=percona-toolkit
pkgver=3.7.0_2
pkgrel=1
pkgdesc="Collection of advanced command-line tools to perform a variety of MySQL and system tasks."
url="https://www.percona.com/software/database-tools/percona-toolkit"
arch=('x86_64')
license=('GPL')
depends=('perl-term-readkey')
makedepends=('perl-dbd-mysql' 'perl-dbi' 'go' 'git')
optdepends=(
    'perl-dbd-mysql: MySQL connections'
    'perl-dbi: MySQL connections'
)
options=('!emptydirs' 'purge' '!lto')
source=("https://github.com/percona/$pkgname/archive/v${pkgver/_/-}/$pkgname-${pkgver/_/-}.tar.gz")
sha256sums=('cecb22c582a61a6955eb3130761d9d0666eb290c917953817cce8e4f92940b48')

prepare() {
    mkdir -p "$srcdir"/src/github.com/percona
    cd "$srcdir"/src/github.com/percona
    mv "$srcdir"/$pkgname-${pkgver/_/-} $pkgname
    cd $pkgname

    sed -ri src/go{,/*}/Makefile \
        -e "s#\\$\\(shell git describe --abbrev=0\\)#v${pkgver/_/-}#" \
        -e "s#\\$\\(shell git rev-(parse|list).* HEAD\\)#v${pkgver/_/-}#" \
        -e "s#\\$\\(shell git rev-parse --show-toplevel\\)#$srcdir/src/github.com/percona/$pkgname#" \
        -e "s#\\$\\(shell basename \`git rev-parse --show-toplevel\`\\)#$pkgname#" \
        -e "s#\\bLDFLAGS\\b#PTLDFLAGS#" \
        -e 's#^PTLDFLAGS="#PTLDFLAGS="-extldflags \\"$(LDFLAGS)\\" #'

    # disable go dep
    sed '/dep ensure/d' -i src/go/Makefile
}

build() {
    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    export CGO_LDFLAGS="${LDFLAGS}"
    export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"

    export GOPATH="$srcdir"
    export PATH="$GOPATH/bin:$PATH"

    cd "$srcdir"/src/github.com/percona/$pkgname
    unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
    export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps MODULEBUILDRC=/dev/null
    perl Makefile.PL INSTALLDIRS=vendor
    make

    cd src/go
    make linux-amd64
}

package() {
    cd "$srcdir"/src/github.com/percona/$pkgname
    unset PERL5LIB PERL_MM_OPT PERL_LOCAL_LIB_ROOT
    make install DESTDIR="$pkgdir"
    rm -rf "$pkgdir"/usr/lib

    mv "$pkgdir/usr/bin/vendor_perl/"* "$pkgdir/usr/bin/"
    rm -r "$pkgdir/usr/bin/vendor_perl/"

    cd bin
    for bin in *; do
        if [ ! -f "$pkgdir/usr/bin/$bin" ]; then
            install -Dm755 "$bin" "$pkgdir/usr/bin/$bin"
        fi
    done
}
