# Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
# Contributor: Jerome Leclanche <jerome@leclan.ch>

pkgname=lxqt-config
pkgver=2.3.0
pkgrel=1
pkgdesc="LXQt system configuration."
arch=("x86_64")
groups=("lxqt")
url="https://github.com/lxqt/$pkgname"
# Upstream licenses are messy and need clarifications... https://github.com/lxqt/lxqt-config/issues/966
license=("LGPL2.1")
depends=("glibc" "gcc-libs"
         "qt6-base" "qt6-svg" "libkscreen"
         "libQt6Xdg.so" "liblxqt" "lxqt-themes" "lxqt-menu-data"
         "libx11" "libxcb" "libxcursor" "libxfixes" "libxi" "xf86-input-libinput"
         "libudev.so" "zlib")
makedepends=("lxqt-build-tools")
optdepends=(
	'xsettingsd: help GTK applications apply themes on the fly'
)
source=(
	"https://github.com/lxqt/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.xz"
	"https://github.com/lxqt/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.xz.asc"
)
sha256sums=('69b8acf50ebedfe3c3808f7dad853e9f5a5e74c8d17693a15180654fcb7f4b0c'
            'SKIP')
validpgpkeys=(
	"19DFDF3A579BD509DBB572D8BE793007AD22DF7E"  # https://github.com/tsujan.gpg
)

build() {
	mkdir -p build
	cd build
	cmake "$srcdir/$pkgname-$pkgver" \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_BUILD_TYPE=None
	make
}

package() {
	cd build
	make DESTDIR="$pkgdir" install
}
