# Maintainer: Felix Yan <felixonmars@archlinux.org>

_hkgname=cabal-plan
pkgname=cabal-plan
pkgver=0.7.3.0
pkgrel=117
pkgdesc="Library and utility for processing cabal's plan.json file"
url="https://github.com/hvr/cabal-plan"
license=("GPL")
arch=('x86_64')
depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-async' 'haskell-base-compat'
         'haskell-base16-bytestring' 'haskell-optics-core' 'haskell-optparse-applicative'
         'haskell-semialign' 'haskell-singleton-bool' 'haskell-tar' 'haskell-these'
         'haskell-topograph' 'haskell-vector' 'haskell-zlib')
makedepends=('ghc' 'uusi')
source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
sha256sums=('ccdc54854b111727d99b77ed6333d9f60c7f5ee0240251b2e4788e005b715e66')

prepare() {
  cd $_hkgname-$pkgver
  uusi -u ansi-terminal -u base-compat -u optparse-applicative
}

build() {
  cd $_hkgname-$pkgver

  runhaskell Setup configure -O --enable-shared --enable-debug-info --enable-executable-dynamic --disable-library-vanilla \
    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=$pkgname --enable-tests \
    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
    --ghc-option='-pie' \
    -fexe -f-license-report

  runhaskell Setup build $MAKEFLAGS
  runhaskell Setup register --gen-script
  runhaskell Setup unregister --gen-script
  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
}

check() {
  cd $_hkgname-$pkgver
  runhaskell Setup test --show-details=direct
}

package() {
  cd $_hkgname-$pkgver

  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
  runhaskell Setup copy --destdir="$pkgdir"
  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE.GPLv2
}
