#!/usr/bin/env perl

use strict;
use warnings;

use JSON;
use Getopt::Long;
use OpenAPI::Linter;

our $VERSION = '0.18';

my $spec;
my $version;
my $json_output     = 0;
my $validate_schema = 0;
my $help            = 0;

GetOptions(
    'json'      => \$json_output,
    'version=s' => \$version,
    'spec=s'    => \$spec,
    'validate'  => \$validate_schema,
    'help'      => \$help,
) or print_usage(2);

print_usage(0) if $help;

if (not $spec) {
    print STDERR "Error: --spec <specfile> is required.\n\n";
    print_usage(2);
}

die "ERROR: Spec file not found: $spec\n" unless (-f $spec);

my $linter = OpenAPI::Linter->new(
    spec    => $spec,
    version => $version,
);

my @issues;
if ($validate_schema) {
    print "Running schema validation for $spec...\n" unless $json_output;
    @issues = $linter->validate_schema;
} else {
    @issues = $linter->find_issues;
}

my ($errors, $warns) = (0, 0);
$errors++ for grep { $_->{level} eq 'ERROR' } @issues;
$warns++  for grep { $_->{level} eq 'WARN'  } @issues;

if ($json_output) {
    print JSON->new->pretty->encode({
        summary => { errors => $errors, warnings => $warns },
        issues  => \@issues,
    });
} else {
    if (@issues) {
        for my $i (@issues) {
            my $message = $i->{message};

            # Apply formatting only to schema validation errors
            if ($validate_schema) {
                print $linter->format_schema_error($message) . "\n";
            }
            else {
                printf "[%s] %s\n", $i->{level}, $message;
            }

            # Print remediation hint if present, indented for readability
            if ($i->{hint}) {
                (my $hint = $i->{hint}) =~ s/^/    /mg;
                print "$hint\n";
            }
        }
        printf "\nSummary: %d ERROR%s, %d WARN%s\n",
            $errors, $errors == 1 ? '' : 's',
            $warns,  $warns  == 1 ? '' : 's';
        exit 1;
    } else {
        print "No issues found.\n";
        exit 0;
    }
}

#
#
# SUBROUTINE

sub print_usage {
    my ($exit_code) = @_;
    print <<'USAGE';
Usage:
  openapi-linter --spec <specfile> [options]

Options:
  --spec <specfile>    Path to OpenAPI specification file (YAML or JSON)
  --version <version>  Specify OpenAPI version (e.g., 3.0.3, 3.1.0)
  --json               Output results in JSON format
  --validate           Run schema validation instead of lint checks
  --help               Show this help message and exit

Examples:
  openapi-linter --spec api.yaml
  openapi-linter --spec api.yaml --validate
  openapi-linter --spec api.yaml --json
  openapi-linter --spec api.yaml --version 3.1.0
USAGE
    exit($exit_code // 0);
}

__END__

=pod

=head1 NAME

openapi-linter - Validate and lint OpenAPI specification files.

=head1 VERSION

Version 0.18

=head1 SYNOPSIS

  openapi-linter --spec api.yaml [options]

=head1 DESCRIPTION

C<openapi-linter> is a command-line utility designed to analyse OpenAPI
(Swagger) specification files for structural correctness and best practices.
It supports both standard linting and strict schema validation.

=head1 OPTIONS

=over 4

=item B<--spec E<lt>specfileE<gt>>

B<Required.> Path to the OpenAPI specification file. Supports both B<YAML> and B<JSON> formats.

=item B<--version E<lt>versionE<gt>>

Explicitly specify the OpenAPI version (e.g., C<3.0.3>, C<3.1.0>). If omitted, the
linter attempts to detect the version from the spec file.

=item B<--json>

Enables machine-readable output. Results will be printed as a pretty-printed
JSON object containing a summary and an array of issues.

=item B<--validate>

Switches mode from general linting to strict schema validation against official
OpenAPI meta-schemas.

=item B<--help>

Displays a brief usage summary and exits.

=back

=head1 EXIT STATUS

=over 4

=item B<0>

Success. No errors or warnings were found.

=item B<1>

Issues found. One or more errors or warnings were detected in the specification.

=item B<2>

Invalid arguments. The script was called with incorrect parameters or a missing spec file.

=back

=head1 EXAMPLES

  # Basic linting
  openapi-linter --spec api.yaml

  # Run strict schema validation
  openapi-linter --spec api.json --validate

  # Output results to a file in JSON format
  openapi-linter --spec api.yaml --json > report.json

=head1 AUTHOR

Mohammad Sajid Anwar, C<< <mohammad.anwar at yahoo.com> >>

=head1 REPOSITORY

L<https://github.com/manwar/OpenAPI-Linter>

=head1 LICENSE AND COPYRIGHT

Copyright (C) 2026 Mohammad Sajid Anwar.

This program  is  free software; you can redistribute it and / or modify it under
the  terms  of the the Artistic License (2.0). You may obtain a  copy of the full
license at:
L<http://www.perlfoundation.org/artistic_license_2_0>
Any  use,  modification, and distribution of the Standard or Modified Versions is
governed by this Artistic License.By using, modifying or distributing the Package,
you accept this license. Do not use, modify, or distribute the Package, if you do
not accept this license.
If your Modified Version has been derived from a Modified Version made by someone
other than you,you are nevertheless required to ensure that your Modified Version
 complies with the requirements of this license.
This  license  does  not grant you the right to use any trademark,  service mark,
tradename, or logo of the Copyright Holder.
This license includes the non-exclusive, worldwide, free-of-charge patent license
to make,  have made, use,  offer to sell, sell, import and otherwise transfer the
Package with respect to any patent claims licensable by the Copyright Holder that
are  necessarily  infringed  by  the  Package. If you institute patent litigation
(including  a  cross-claim  or  counterclaim) against any party alleging that the
Package constitutes direct or contributory patent infringement,then this Artistic
License to you shall terminate on the date that such litigation is filed.
Disclaimer  of  Warranty:  THE  PACKAGE  IS  PROVIDED BY THE COPYRIGHT HOLDER AND
CONTRIBUTORS  "AS IS'  AND WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES. THE IMPLIED
WARRANTIES    OF   MERCHANTABILITY,   FITNESS   FOR   A   PARTICULAR  PURPOSE, OR
NON-INFRINGEMENT ARE DISCLAIMED TO THE EXTENT PERMITTED BY YOUR LOCAL LAW. UNLESS
REQUIRED BY LAW, NO COPYRIGHT HOLDER OR CONTRIBUTOR WILL BE LIABLE FOR ANY DIRECT,
INDIRECT, INCIDENTAL,  OR CONSEQUENTIAL DAMAGES ARISING IN ANY WAY OUT OF THE USE
OF THE PACKAGE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

=cut
